IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)



Peut-on changer la police ou la couleur du texte avec MsgBox ?
Non. Vous devrez donc programmer vos propres boîtes de message avec une form qui aura la valeur fixedSingle à la propriété BorderStyle pour qu'elle ne soit pas redimensionnable, et la valeur CenterScreen pour StartUpPosition.

Comment faire une barre de progression ?
Voici deux solutions : la faire vous même avec un PictureBox, ou utiliser le contrôle ProgressBar contenu dans le composant Microsoft Windows Common Controls 6.0. Voyons un exemple illustrant la première méthode; posez un PictureBox et un timer sur une form, et placez ce code dans le module de la form :
Dim niveau as long, max as long

Private Sub Form_Load()

max = 100    'valeur maximale du niveau
niveau = 0   'valeur initiale
Timer1.Interval = 200
Picture1.Width = 5000
Picture1.Height = 280

End Sub 

Private Sub Timer1_Timer()

niveau = niveau + 1
If niveau = max Then Timer1.Enabled = False
Picture1.Line (0, 0)-(niveau * Picture1.ScaleWidth / max, Picture1.ScaleHeight), vbBlue, BF 

End Sub
Et maintenant voici l'équivalent avec le contrôle ProgressBar. Posez sur une form un timer et un contrôle ProgressBar, et placez ce code dans le module de la form :
Private Sub Form_Load()

ProgressBar1.min = 0
ProgressBar1.max = 100
ProgressBar1.Value = 0
Timer1.Interval = 200

End Sub

Private Sub Timer1_Timer()

ProgressBar1.Value = ProgressBar1.Value + 1
If ProgressBar1.Value >= ProgressBar1.max Then Timer1.Enabled = False

End Sub

Comment modifier le texte d'un rptLabel dans un datareport ?
Exemple pour un label nommé "lblDateImp" qui est dans la section "sctEntete" :
Datareport1.Sections("sctEntete").controls("lblDateImp").caption = "Imprimé le " & date

Comment afficher un DataReport en mode paysage ?
Si vous n'avez pas installé le Service Pack 4 ou une version ultérieure pour Microsoft Visual Studio 6, le DataReport utilise la configuration de l'imprimante par défaut pour choisir entre le mode portrait et le mode paysage. Les Service Packs 4 et supérieurs contiennent une mise à jour de l'objet DataReport, qui possède une nouvelle propriété appelée Orientation. Le code suivant utilise cette propriété afin d'afficher un DataReport en mode paysage :
DataReport1.Orientation = rptOrientLandscape
DataReport1.Show

Comment faire défiler un ensemble de contrôles avec un ascenseur ?
Placez sur une form une frame nommée Frame1. Sélectionnez-la, et placez dans cette frame une autre frame, nommée Frame2.
Frame1 doit être le conteneur de Frame2 et la hauteur de Frame2 doit être supérieure à celle de Frame1. Mettez la propriété Top de Frame2 à 0. Puis placez les contrôles qui devront défiler dans Frame2. Enfin ajoutez ce code dans le module de la form :
Private Sub Form_Load()

VScroll1.Min = 0
VScroll1.Max = Frame2.Height - Frame1.Height

End Sub

Private Sub VScroll1_Change()

Frame2.Top = -VScroll1.Value

End Sub

Private Sub VScroll1_Scroll()

VScroll1_Change

End Sub
Vous pouvez aussi utiliser des PictureBox, mais les frames consomment moins de ressources.


Ce document issu de http://www.developpez.com est soumis à la licence GNU FDL traduit en français ici.
Permission vous est donnée de distribuer, modifier des copies de cette page tant que cette note apparaît clairement.